Windows 10 – 8 – 7 ürün anahtarı bulma

Windows 10 – 8 – 7 ürün anahtarı bulma

 

Windows ürün anahtarınızı nerede sakladığınızı unuttuysanız veya tamamen bilmiyorsanız, yanlızca kurulum sırasında giriş yaptıktan sonra windows 10 ürün anahtarı bulma diğer bir önceki versiyonu olan windows 8 ve windows 7 için ürün anahtarı bulma işlemi aynı script üzerinden yapılır. Aşağıda belirtilen çözümü adım adım uygulayın.Resimli olarak belirttim. Şimdi vir visual basic script dosyası ile Windows 10’un, Windows 8’in veya Windows 7’nin bilgisayara yüklenmiş olan serial nosunu ürün anahtarını göstermenin nasıl yapılacağını inceleyelim. Ürün anahtarınızı PC’nizde yüklü olan işletim sisteminden bulmak için scripti sizinle paylaşıyorum.

Windows 10 – 8 – 7 ürün anahtarı bulma

1- Notepad programını açalım.

2- Aşağıdaki kod bölümünü yapıştıralım.

 

Option Explicit  
 
Dim objshell,path,DigitalID, Result  
Set objshell = CreateObject("WScript.Shell") 
'Set registry key path 
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\" 
'Registry key value 
DigitalID = objshell.RegRead(Path & "DigitalProductId") 
Dim ProductName,ProductID,ProductKey,ProductData 
'Get ProductName, ProductID, ProductKey 
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName") 
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID") 
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)  
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey 
'Show messbox if save to a file  
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then 
   Save ProductData  
End If 
 
 
 
'Convert binary to chars 
Function ConvertToKey(Key) 
    Const KeyOffset = 52 
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert 
    'Check if OS is Windows 8 
    isWin8 = (Key(66) \ 6) And 1 
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4) 
    i = 24 
    Maps = "BCDFGHJKMPQRTVWXY2346789" 
    Do 
           Current= 0 
        j = 14 
        Do 
           Current = Current* 256 
           Current = Key(j + KeyOffset) + Current 
           Key(j + KeyOffset) = (Current \ 24) 
           Current=Current Mod 24 
            j = j -1 
        Loop While j >= 0 
        i = i -1 
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput 
        Last = Current 
    Loop While i >= 0  
     
    If (isWin8 = 1) Then 
        keypart1 = Mid(KeyOutput, 2, Last) 
        insert = "N" 
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0) 
        If Last = 0 Then KeyOutput = insert & KeyOutput 
    End If     
     
 
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5) 
    
     
End Function 
'Save data to a file 
Function Save(Data) 
    Dim fso, fName, txt,objshell,UserName 
    Set objshell = CreateObject("wscript.shell") 
    'Get current user name  
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")  
    'Create a text file on desktop  
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt" 
    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set txt = fso.CreateTextFile(fName) 
    txt.Writeline Data 
    txt.Close 
End Function

 

3- Dosya bölümünden farklı kaydederek masa üstüne kaydetmeden bir verelim ve ismin sonuna .vbs formatını ekleyelim.Örnek Anahtarbulma.vps kaydedip kapatalım.

Windows 10 – Windows 8 – Windows 7 Ürün Anahtarı Bulma

4 – anahtarbulma.vps dosyasını çift tıklayarak açalım.Bize ürün anaharını gösteren bir kutu açılacakAşağıdaki ekran karşımıza gelecektir.Eğer yes butonuna basarsanız anahtarbulma.vps dosyasını kaydettiğiniz dizine windows serialinizi bir text dökümanı olarak kaydedecektir.Windows 10 – 8 – 7 ürün anahtarı bulma

Windows 10 – Windows 8 – Windows 7 Ürün Anahtarı Bulma 2

Ayrıca Buna Bakabilirsiniz

Dns Adresi Değiştirme yasaklı sitelere giriş

Dns Adresi Değiştirme Dns Adresi Değiştirme Ülkemizde yeni bir karar olarak Youtube adlı video erişim …